Classi

na famiglie Nome { … } dichiara una classe (class). Il costruttore(…) prepara l'oggetto e nu bell Nome(…) ne crea uno nuovo (new).

figlio 'e eredita da un'altra classe (extends) e 'o pate chiama la classe madre (super). fisso rende un metodo statico (static), damme e miette creano getter e setter. I campi con # sono privati.

na famiglie Persona {
    costruttore(nome) {
        stu cos.nome = nome
    }

    saluta() {
        piglie "Uè, so' " + stu cos.nome
    }
}

na famiglie Pizzaiolo figlio 'e Persona {
    #pizze = 0

    costruttore(nome) {
        'o pate(nome)
    }

    sforna() {
        stu cos.#pizze++
    }

    damme pizze() {
        piglie stu cos.#pizze
    }

    fisso mestiere() {
        piglie "pizzaiolo"
    }
}

chist è gennaro = nu bell Pizzaiolo("Gennaro")
gennaro.sforna()
gennaro.sforna()
stamm a dì(gennaro.saluta(), gennaro.pizze)
stamm a dì(Pizzaiolo.mestiere(), gennaro è uno Persona)

Output

Uè, so' Gennaro 2
pizzaiolo true

Prova questa sezione nel playground